This is a set of Parent and Child Check-in labels. These labels are 3x2, and make use of the Rock Icon Font. Instructions for setup are listed below, and a PDF explaining each label is available for download.

There are 4 steps to setting up these labels:

• Installing the Rock Icon Font
• Setting up a new Label Merge Field
• Setting up the Child Label
• Setting up the Parent Label

Prerequisites

• Install the Rock Icon Font (https://community.rockrms.com/documentation/bookcontent/10/187#installingtherockiconfontonzebraprinters)

Set Up new Label Merge Field

Go to Admin Tools -> Check-in, Label Merge Fields, and create a new Merge Field with the following properties:

• Value
  Group Name and Location
• Description
  The name and times that person checked into
• MergeField
  

  {% for group in GroupType.Groups %}
    {% for location in group.Locations %}
      {% if forloop.index > 1 %}; {% endif %}
      {{group.Name}}
      {% for schedule in location.Schedules %} - {{schedule.Name}}
      {% endfor %}
    {% endfor %}
  {% endfor %}
  

Click Save when you're done

Set up the Child Label

Go to Admin Tools -> Check-in, Check-in Labels, and create a new Label with the following properties:

• File Name
  My Child Label
• Mime Type
  text/plain
• Print For Each
  Person

Save, and then edit the Label you just created. Click Edit Label Contents, and paste in the following:

CT~~CD,~CC^~CT~
^XA~TA000~JSN^LT0^MNW^MTD^PON^PMN^LH0,0^JMA^PR6,6~SD24^LRN^CI28^XZ
^XA
^MMT
^PW609
^LL0406
^LS0

^FX Label Contents Below This Line ^FS

^FX Header ^FS
^CWZ,ROC000.FNT
^FO40,32^AZ,55,55^FDB^FS
^FO100,32^AZ,55,55^FDF^FS
^FO160,32^AZ,55,55^FDA^FS
^FO220,32^AZ,55,55^FDL^FS
^FT580,77,1^A0N,75,75^FDABC^FS
^FR^FO0,0^GB609,0,90^FS

^FX Date ^FS
^FT580,120,1^A0N,25,25^FDDATE^FS

^FX Child Name ^FS
^FB609,1,0,C^FT0,160^A0N,70,70^FDFIRSTNAME^FS
^FB609,1,0,C^FT0,200^A0N,40,40^FDLASTNAME^FS

^FX Allergies ^FS
^FB250,4,0,L^FT30,310^A0N,25,25^FDALLERGYNOTE^FS
^FB250,4,0,L^FT300,310^A0N,25,25^FDLEGALNOTE^FS

^FX Location ^FS
^FB609,1,0,C^FT0,390^A0N,30,30^FDLOCATION^FS

^FX Label Contents Above This Line ^FS

^PQ1,0,1,Y^XZ

Set the Label Size to 3x2, then click Save.

Finally, add the following Merge Codes:

• B: Birthday Icon
• F: Birthday Icon
• A: Allergy Icon
• L: Legal Icon
• ABC: Security Code
• DATE: Current Day/Date
• FIRSTNAME: Nick Name
• LASTNAME: Last Name
• ALLERGYNOTE: Allergy Note
• LEGALNOTE: Legal Note
• LOCATION: Group Name and Location (the one we just created)

Click Save

Set up the Parent Label

Go to Admin Tools -> Check-in, Check-in Labels, and create a new Label with the following properties:

• File Name
  My Parent Label
• Mime Type
  text/plain
• Print For Each
  Person

Save, and then edit the Label you just created. Click Edit Label Contents, and paste in the following:

CT~~CD,~CC^~CT~
^XA~TA000~JSN^LT0^MNW^MTD^PON^PMN^LH0,0^JMA^PR6,6~SD24^LRN^CI28^XZ
^XA
^MMT
^PW609
^LL0406
^LS0

^FX Label Contents Below This Line ^FS

^FX Header ^FS
^FB609,1,0,C^FT0,70^A0N,48,48^FDChild Pickup Receipt^FS
^FR^FO0,0^GB609,0,90^FS

^FX Date ^FS
^FT580,120,1^A0N,25,25^FDDATE^FS

^FX Child Name ^FS
^FB609,1,0,C^FT0,160^A0N,70,70^FDFIRSTNAME^FS
^FB609,1,0,C^FT0,200^A0N,40,40^FDLASTNAME^FS

^FX Security Code ^FS
^FB609,1,0,C^FT0,295^A0N,80,80^FDABC^FS

^FX Safety notice ^FS
^FB539,2,0,C^FT30,390^A0N,30,30^FDFor the safety of your child, you must present this receipt at pickup.^FS

^FX Label Contents Above This Line ^FS

^PQ1,0,1,Y^XZ

Set the Label Size to 3x2, then click Save.

Finally, add the following Merge Codes:

• ABC: Security Code
• DATE: Current Day/Date
• FIRSTNAME: Nick Name
• LASTNAME: Last Name

Click Save